dotfiles/hosts/lolcathost/default.nix

{
  pkgs,
  inputs,
  ...
}: let
  home-manager = builtins.fetchTarball {
    url = "https://github.com/nix-community/home-manager/archive/release-24.11.tar.gz";
    sha256 = "0gjfa3bv0m0kymxqla9iih11gjb6czyj942v34pyc7xy4qsx898k";
  };
in {
  imports = [
    ./hardware-configuration.nix
    (import "${home-manager}/nixos")
    inputs.spicetify-nix.nixosModules.default

    ../modules/steam.nix
    ../modules/obsidian.nix

    ../modules/angryoxide.nix
    ../modules/flipperzero.nix
    ../modules/chameleonultragui.nix
  ];

  programs.spicetify = let
    spicePkgs = inputs.spicetify-nix.legacyPackages.${pkgs.system};
  in {
    enable = true;
    enabledExtensions = with spicePkgs.extensions; [
      adblock
      hidePodcasts
      shuffle # shuffle+ (special characters are sanitized out of extension names)
    ];
    #theme = spicePkgs.themes.catppuccin;
    #colorScheme = "mocha";
  };

  boot.loader = {
    efi = {
      canTouchEfiVariables = true;
      efiSysMountPoint = "/boot/efi";
    };
    grub = {
      efiSupport = true;
      #efiInstallAsRemovable = true; # in case canTouchEfiVariables doesn't work on this system
      device = "nodev";
      useOSProber = false;
    };
    # GitHub: vinceliuice/grub2-themes
    grub2-theme = {
      enable = true;
      theme = "whitesur"; # stylish, vimix, or whitesur
      footer = true;
      customResolution = "1920x1080"; # Optional: Set a custom resolution
    };
  };

  # Set your time zone.
  time.timeZone = "Australia/Brisbane";

  # Select internationalisation properties.
  i18n.defaultLocale = "en_US.UTF-8";
  # Enable initrd hook for virtual console customisation
  # aka cool colours when bootting yay!!
  console = {
    enable = true;
    earlySetup = true; # initrd pre hook
    keyMap = "us";
    font = "Lat2-Terminus16";
    # ANSI 24-bit color definitions (theme: dracula)
    colors = [
      "21222c"
      "ff5555"
      "50fa7b"
      "f1fa8c"
      "bd93f9"
      "ff79c6"
      "8be9fd"
      "f8f8f2"
      "6272a4"
      "ff6e6e"
      "69ff94"
      "ffffa5"
      "d6acff"
      "ff92df"
      "a4ffff"
      "ffffff"
    ];
  };

  # ----- NETWORKING SECTION -----
  networking.hostName = "lolcathost";
  networking.networkmanager.enable = true;

  # Open ports in the firewall.
  #networking.firewall.allowedTCPPorts = [ ... ];
  # networking.firewall.allowedUDPPorts = [ ... ];
  # Or disable the firewall altogether.
  networking.firewall.enable = false;

  # ----- SERVICES -----
  services = {
    # Set display manager (login screen)
    displayManager = {
      # sddm relies on pkgs.libsForQt5.qt5.qtgraphicaleffects
      sddm = {
        enable = true;
        wayland.enable = true; # enable experimental sddm support for wayland
        theme = "corners";
      };
      defaultSession = "hyprland";
    };

    # Enable sound
    #hardware.pulseaudio.enable = false;
    pipewire = {
      enable = true;
      wireplumber.enable = true;

      alsa.enable = true;
      alsa.support32Bit = true;
      pulse.enable = true;
      jack.enable = true;
    };

    # Enable touchpad support
    libinput.enable = true;

    tumbler.enable = true; # Thunar image thumbnail support
    gvfs.enable = true; # Thunar mount, trash, and other functionality
  };
  security.rtkit.enable = true; # I *think* this is for pipewire

  # allow wheel group to use passwordless sudo
  users = {
    # using fish as the login shell tends
    # to go very poorly because it isn't
    # POSIX compliant, so we'll just use
    # simple Bash then :)
    defaultUserShell = pkgs.bash;

    users = {
      # literally me fr (personal account)
      me = {
        isNormalUser = true;
        extraGroups = ["wheel" "netdev" "docker"];
        shell = pkgs.bash; #pkgs.fish
        packages = let
          # TODO: can I just do this: https://nix.dev/manual/nix/2.18/command-ref/new-cli/nix3-flake#url-like-syntax
          #       instead to use colmena's flake.nix by specifying a rev hash in the flake input?
          colmena-src = pkgs.fetchFromGitHub {
            owner = "zhaofengli";
            repo = "colmena";
            rev = "47b6414d800c8471e98ca072bc0835345741a56a";
            sha256 = "rINodqeUuezuCWOnpJgrH7u9vJ86fYT+Dj8Mu8T/IBc=";
          };
          colmena-latest = pkgs.callPackage "${colmena-src}/package.nix" {};
        in
          with pkgs; [
            firefox
            nitch
            starfetch

            hyprpanel

            # flatpak requires gnome-software
            # for graphical applications
            flatpak
            gnome-software

            colmena-latest

            jetbrains.rider
            gitkraken
          ];
      };

      # user for my professional jobs and stuff
      ae = {
        isNormalUser = true;
        extraGroups = ["wheel"];
        shell = pkgs.bash; #pkgs.fish
        packages = with pkgs; [
        ];
      };

      # # This is the user account for servers
      # dev = {
      #   isNormalUser = true;
      #   extraGroups = ["wheel"];
      #   shell = pkgs.bash; #pkgs.zsh
      #   packages = with pkgs; [
      #   ];
      # };

      # user for friends to ssh into
      friends = {
        isNormalUser = true;
        shell = pkgs.fish;
        packages = with pkgs; [
        ];
      };
    };
  };

  home-manager = {
    users.me = import ../../homes/me;
    #extraSpecialArgs = {inherit inputs pkgs;};
    sharedModules = [
      inputs.ags.homeManagerModules.default
      inputs.nixcord.homeManagerModules.nixcord
      #{nixpkgs.overlays = [inputs.hyprpanel.overlay];}
    ];
  };

  # set environment variables
  environment.sessionVariables = {
    # folder names with capitalisation look awful!
    XDG_DOWNLOAD_DIR = "$HOME/downloads";

    # Hint Electrons apps to use Wayland
    NIXOS_OZONE_WL = "1";
  };

  # ---- SYSTEM PACKAGES -----
  environment.systemPackages = with pkgs; [
    # User Environment
    inputs.swww.packages.${pkgs.system}.swww
    helvum
    easyeffects
    ani-cli
    wl-clipboard # clipboard for wayland
    pavucontrol
    qbittorrent # torrenting

    (callPackage ../sddm-theme-corners.nix {}).sddm-theme-corners
    # dependencies for my sddm theme:
    pkgs.libsForQt5.qt5.qtgraphicaleffects

    python312 # I use 3.12 since it's in a pretty stable state now
    python314 # also 3.14 for latest features
    poetry # python dependency management and packaging
    clang-tools

    nim-2_2
    nimble
    # nimlangserver # FUCK THIS LSP, ITS AWFUL WITH HELIX

    sageWithDoc # SageMath + HTML Documentation

    # DEBUG: using neofetch temporarily to see if my system upgrades properly
    neofetch

    openvpn
    inetutils

    # fish plugins
    grc # colorise command outputs

    httpie
    curlie
    zoxide
    doggo
    tldr
    # btop
    eza
    ripgrep
    viddy # modern `watch` command

    # TODO: once upgraded past Nix-24.07 this line won't be necessary (I think)
    #       helix will support nixd by default
    # SOURCE: https://github.com/nix-community/nixd/blob/main/nixd/docs/editor-setup.md#Helix
    nixd # lsp for nix

    # Pretty necessary
    git
    git-filter-repo
    brightnessctl
    acpi
    # upower
    vim
    powertop
    gcc
    gnumake
    imagemagick

    # Unix Commands
    wget
    tree
    unzip
    unrar-free
    # Man Pages
    man-pages
    man-pages-posix
  ];

  # Enable the use of certain programs
  programs = {
    hyprland = {
      enable = true;
      #package = inputs.hyprland.packages.${pkgs.stdenv.hostPlatform.system}.hyprland;
      #portalPackage = inputs.hyprland.packages.${pkgs.stdenv.hostPlatform.system}.xdg-desktop-portal-hyprland;

      xwayland.enable = true;
    };

    zsh.enable = true;
    fish.enable = true;

    nix-ld.enable = true;

    # I want to use fish as my login shell but it always goes terrible
    # cause it isn't POSIX compliant, so instead Bash is my login and
    # will just exec fish (^-^)
    bash = {
      completion.enable = true;

      interactiveShellInit = ''
        if [[ $(${pkgs.procps}/bin/ps --no-header --pid=$PPID --format=comm) != "fish" && -z ''${BASH_EXECUTION_STRING} ]]
        then
          shopt -q login_shell && LOGIN_OPTION='--login' || LOGIN_OPTION=""
          exec ${pkgs.fish}/bin/fish $LOGIN_OPTION
        fi
      '';
    };

    # Thunar also uses: `services.tumbler` & `services.gvfs`
    thunar = {
      enable = true;
      plugins = with pkgs.xfce; [
        thunar-volman # for removable drives (ie USBs)
        thunar-archive-plugin # create and extract archives
        thunar-media-tags-plugin # change metadata for media files
      ];
    };
  };

  # ----- FONTS -----
  fonts = {
    enableDefaultPackages = true; # no clue what this line does tbh
    packages = with pkgs; [
      #(nerdfonts.override {
      #  fonts = [
      #    "Cousine"
      #    "Iosevka"
      #     "JetBrainsMono"
      #   ];
      # })
      nerdfonts
      geist-font # for my hyprlock theme

      # texlive maintains a noto-emoji flake
      texlivePackages.noto-emoji
    ];

    # TODO: change my default fonts
    fontconfig = {
      defaultFonts = {
        serif = ["Geist"]; # TODO: package Iosevka Etoile since Iosevka isn't a serif font
        sansSerif = ["Geist"];
        monospace = ["Cousine"];
        emoji = ["Noto Emoji"];
      };
    };
  };

  # Enable the new CLI commands and the flakes as experimental features
  nix.settings.experimental-features = [
    "nix-command"
    "flakes"
  ];

  virtualisation.docker.enable = true;

  # Some programs need SUID wrappers, can be configured further or are
  # started in user sessions.
  # programs.mtr.enable = true;
  # programs.gnupg.agent = {
  #   enable = true;
  #   enableSSHSupport = true;
  # };

  # Enable the OpenSSH daemon.
  # services.openssh.enable = true;

  # Enable OpenGL
  hardware = {
    graphics.enable = true;

    # opengl = {
    #   enable = true;
    #   driSupport = true;
    #   driSupport32Bit = true;
    # }
  };

  # DO NOT MODIFY
  system.stateVersion = "24.05"; # Did you read the comment?
}